물리적인 이해(Getting Physical)¶

물리적 의미의 단위(Physical Unit)¶

이 섹션에서 이미 언급했듯이, 여기서 보이는 예제는 실제 시스템의 개별 속성에 해당하는 개별 물리적 parameter를 포함하기 때문에 좀 더 물리적입니다. 그러나 여전히 뭔가를 놓치고 있습니다. 이러한 변수는 온도, 질량 등 과 같은 물리적 양을 나타내지만 물리적 자료형을 명시적으로 지정하지는 않았습니다.

이미 짐작하셨겠지만 T 변수는 온도입니다.이는 변수와 관련된 설명 텍스트에서 명확하게 나타납니다. 또한 T0 및 T_inf 도 분명히 온도이여야만 한다는 부분을 결정하기 위해, 이전의 모델을 심도 있게 해석하지 않습니다.

그러나 h 또는 A 와 같은 다른 변수는 어떻게 해야 할 까요? 이 변수는 무엇을 대표하는 것인가요? 사실 더욱 중요한 것은, 방정식이 물리적으로 일치하는가? 하는 것입니다. 물리적으로 일치한다는 것은 방정식의 양쪽이 동일한 물리적 단위(예:, 온도, 질량, 전력)를 갖는다는 것을 의미합니다.

아래에서 보여지는 것 처럼, 모델리카에서는 실제 변수를 선언하는 구문에서 변수를 선언하는 것 뿐 아니라 다양한 변수의 물리적 단위를 포함하여서 엄격하게 정의 할 수 있습니다.

model NewtonCoolingWithUnits "Cooling example with physical units"
  parameter Real T_inf(unit="K")=298.15 "Ambient temperature";
  parameter Real T0(unit="K")=363.15 "Initial temperature";
  parameter Real h(unit="W/(m2.K)")=0.7 "Convective cooling coefficient";
  parameter Real A(unit="m2")=1.0 "Surface area";
  parameter Real m(unit="kg")=0.1 "Mass of thermal capacitance";
  parameter Real c_p(unit="J/(K.kg)")=1.2 "Specific heat";

  Real T(unit="K") "Temperature";
initial equation
  T = T0 "Specify initial value for T";
equation
  m*c_p*der(T) = h*A*(T_inf-T) "Newton's law of cooling";
end NewtonCoolingWithUnits;

이제 각 변수 선언에는 (unit="...") 라는 텍스트가 포함되어 물리적 단위를 변수와 연결합니다. 이 추가 텍스트가 하는 일은 변수와 관련된 unit 속성에 대한 값을 지정하는 것입니다. 속성(attributes)은 각 변수가 갖는 특별한 특성입니다. 변수가 가질 수 있는 속성 집합은 변수의 자료형에 따라 다릅니다.(이에 대해서는 다음 섹션에서 자세히 설명합니다. 변수(Variables) )

언뜻 보기에 단위 속성 (예를들어, (unit="K") )을 지정하는 것이 단순히 변수 다음의 설명 문자열로 "Temperature" 를 추가하는 것보다 나은 이유가 명확하지 않을 수 있습니다. 사실 Temperature 가 K 와 같은 단일 문자보다 더 설명적이기 때문에 더 나쁘다고 주장할 수도 있습니다.

그러나 unit 속성을 설정하는 것은 실제로 두 가지 이유로 더 형식적인 접근 방식입니다. 첫 번째 이유는 모델리카 사양이 모든 표준 SI 단위 속성(예:, K, kg, m)에 대한 관계를 정의하기 때문입니다. 여기에는 다른 기본 단위(예:, N)로 구성될 수 있는 복합 단위의 자료형이 포함됩니다.

또 다른 이유는 모델리카 사양이 복잡한 수학적 표현의 단위를 계산하는 방법에 대한 규칙도 정의하기 때문입니다. 이러한 방식으로 모델리카 사양은 모델리카 모델의 오류 또는 물리적 불일치를 단위 확인 하는 데 필요한 모든 것을 정의합니다. 단위를 추가하면 모델이 더 명확해질 뿐만 아니라 오류 발생 시 더 나은 진단을 제공하기 때문에 이는 모델 개발자에게 큰 도움이 됩니다.

물리적 자료형(Physical Types)¶

그러나 사실을 말하자면, NewtonCoolingWithUnits 예제 코드에는 한 가지 단점이 있으며, 모든 변수에 대해 unit 속성 지정을 반복해야 한다는 것입니다. 게다가 앞서 언급했듯이 K 는 "Temperature"만큼 설명적이지 않습니다.

다행스럽게도 모델리카를 사용하면 derived types - 파생 자료형 을 정의할 수 있기 때문에 두 가지 문제에 대한 간단한 해가 됩니다. 지금까지 선언한 모든 변수는 Real 자료형이었습니다. Real 의 문제는 그것이 무엇이든 될 수 있다는 것입니다. (예를들어, 전압, 전류, 온도). 하고 싶은 것은 이러한 범위를 조금 좁히는 것입니다.여기에서 파생 자료형이 사용되고 있습니다. 파생 자료형을 정의하고 선언에서 사용하는 방법을 다음 예제로 살펴보겠습니다.

model NewtonCoolingWithTypes "Cooling example with physical types"
  // Types
  type Temperature=Real(unit="K", min=0);
  type ConvectionCoefficient=Real(unit="W/(m2.K)", min=0);
  type Area=Real(unit="m2", min=0);
  type Mass=Real(unit="kg", min=0);
  type SpecificHeat=Real(unit="J/(K.kg)", min=0);

  // Parameters
  parameter Temperature T_inf=298.15 "Ambient temperature";
  parameter Temperature T0=363.15 "Initial temperature";
  parameter ConvectionCoefficient h=0.7 "Convective cooling coefficient";
  parameter Area A=1.0 "Surface area";
  parameter Mass m=0.1 "Mass of thermal capacitance";
  parameter SpecificHeat c_p=1.2 "Specific heat";

  // Variables
  Temperature T "Temperature";
initial equation
  T = T0 "Specify initial value for T";
equation
  m*c_p*der(T) = h*A*(T_inf-T) "Newton's law of cooling";
end NewtonCoolingWithTypes;

물리적 단위가 Kelvin(K)이고 가능한 최소값이 0 인 Real 형태인 Temperature 를 내부에서 정의할 때,``type Temperature=Real(unit="K", min=0);`` 으로 새로운 자료형을 정의할 수 있습니다.

이 예제에서 Temperature 와 같은 물리적 자료형을 사전에 정의하면 이를 사용하여, 동일 한 특성을 가지는 다수의 변수(예를들어, T, T_inf 및 T0 )에 대해서 각각 unit 또는 min 속성을 지정하지 않아도 됩니다. 또한 SI 단위인 K 대신 Temperature 라는 친숙한 이름을 사용하게 됩니다. 파생 자료형을 만들 때 사용할 수 있는 다른 속성이 무엇인지 궁금 하다면, 관련한 더 자세한 논의는 내장 자료형(Built-In Types) 섹션을 참조하십시오.

이 시점에서 모든 모델에서 Temperature, ConvectionCoefficient, SpecificHeat 및 Mass 를 정의하는 것이 매우 번거롭다는 것을 알 수 있습니다. 정말 필요하다면 그렇게 해야 할 것입니다만, 걱정하지 않아도 됩니다. 물리적 자료형 가져오기(Importing Physical Types) 섹션에서 볼수 있듯이 이에 대한 쉬운 해결책을 이후에 논의하겠습니다.