구성요소 모델(Component Models)¶

커넥터(Connectors)¶

비인과적 모델링의 또 다른 이점은 이 접근 방식으로 수행되는 자동 "계산"의 양입니다. 어떤 계정이 수행되는지 정확히 이해하기 위해 모델리카 표준 라이브러리에서 다음과 같은 회전식 connector 정의를 살펴보겠습니다.

connector Flange_a "1-dim. rotational flange of a shaft (filled square icon)"
  Modelica.SIunits.Angle phi "Absolute rotation angle of flange";
  flow Modelica.SIunits.Torque tau "Cut torque in the flange";
  annotation ...
end Flange_a;

connector Flange_b "1-dim. rotational flange of a shaft (filled square icon)"
  Modelica.SIunits.Angle phi "Absolute rotation angle of flange";
  flow Modelica.SIunits.Torque tau "Cut torque in the flange";
  annotation ...
end Flange_b;

이전에 논의한 바와 같이 비인과적 커넥터에는 변수 사이 혹은 변수를 통과하는 두 가지 다른 자료형의 변수가 존재합니다.통과 변수는 flow 한정자로 표시합니다.``Rotational`` 커넥터의 경우 교차 변수는 각도 위치인 phi 이고 통과 변수는 토크인 tau 입니다.

부호 체계(Sign Conventions)¶

또한 모델리카 모델은 다음 규칙을 준수해야 한다고 했던 이전 논의를 기억하겠습니다. 이것은 모든 계산이 정확한지 확인할 뿐만 아니라 스프링, 댐퍼 등 과 같은 (본질적으로 대칭인) 구성 요소가 뒤집어져도 여전히 동일하게 작동하도록 함으로써 구성 가능성에도 도움이 되기 때문에 중요한 규칙입니다.

연결 세트(Connection Sets)¶

컴파일러가 수행하는 계산에 대해 자세히 알아보기 전에 연결 세트 의 개념을 소개해야 합니다. 연결 세트가 무엇인지 설명하려면 다음 도식을 참고 할 수 있습니다.

이 모델에는 8개의 연결이 있습니다.

equation
  connect(ground.flange_a, damper2.flange_b);
  connect(ground.flange_a, spring2.flange_b);
  connect(damper2.flange_a, inertia2.flange_b);
  connect(spring2.flange_a, inertia2.flange_b);
  connect(inertia2.flange_a, damper1.flange_b);
  connect(inertia2.flange_a, spring1.flange_b);
  connect(damper1.flange_a, inertia1.flange_b);
  connect(spring1.flange_a, inertia1.flange_b);

두 개의 연결 문에 하나의 커넥터가 공통으로 있는 경우 동일한 연결 집합에 속합니다. 커넥터가 다른 커넥터에 연결되어 있지 않으면 자신만 포함하는 연결 세트에 속합니다. 이 규칙을 사용하여 커넥터를 다음과 같이 연결 세트로 구성할 수 있습니다.

• Connection Set #1

  • ground.flange_a

  • damper2.flange_b

  • spring2.flange_b

• Connection Set #2

  • damper2.flange_a

  • spring2.flange_a

  • inertia2.flange_b

• Connection Set #3

  • inertia2.flange_a

  • damper1.flange_b

  • spring1.flange_b

• Connection Set #4

  • inertia1.flange_b

  • damper1.flange_a

  • spring1.flange_a

• Connection Set #5

  • inertia1.flange_a

이러한 연결 세트는 다이어그램에서 오른쪽에서 왼쪽으로 나타납니다.시간을 들여 다이어그램의 커넥터를 연결 세트에 나열된 커넥터와 일치시켜 연결 세트가 무엇인지 직관적으로 이해하는 것이 유용할 수 있습니다. flange_a 커넥터는 채워진 원이고 flange_b 커넥터는 외곽선만 표시됩니다.

만들어진 방정식(Generated Equations)¶

여기에서 "계산"이 시작됩니다. 각 연결 설정 에 대해 특수 방정식이 자동으로 생성됩니다. 첫 번째 자동 방정식 세트는 교차 변수와 관련된 것인데, 수학적으로 말해서 모든 변수가 동일한 값을 가져야 한다는 제약을 부과합니다. 다음으로, 연결 세트의 모든 통과 변수의 합이 0이 되어야 한다는 공식이 필요 합니다.

위 연결 세트의 경우 다음 방정식이 자동으로 생성됩니다.

// Connection Set #1
//   Equality Equations:
ground.flange_a.phi = damper2.flange_b.phi;
damper2.flange_b.phi = spring2.flange_b.phi;
//   Conservation Equation:
ground.flange_a.tau + damper2.flange_b.tau + spring2.flange_b.tau = 0;

// Connection Set #2
//   Equality Equations:
damper2.flange_a.phi = spring2.flange_a.phi;
spring2.flange_a.phi = inertia2.flange_b.phi;
//   Conservation Equation:
damper2.flange_a.tau + spring2.flange_a.tau + inertia2.flange_b.tau = 0;

// Connection Set #3
//   Equality Equations:
inertia2.flange_a.phi = damper1.flange_b.phi;
damper1.flange_b.phi = spring1.flange_b.phi;
//   Conservation Equation:
inertia2.flange_a.tau + damper1.flange_b.tau + spring1.flange_b.tau = 0;

// Connection Set #4
//   Equality Equations:
inertia1.flange_b.phi = damper1.flange_a.phi;
damper1.flange_a.phi = spring1.flange_a.phi;
//   Conservation Equation:
inertia1.flange_b.tau + damper1.flange_a.tau + spring1.flange_a.tau = 0;

// Connection Set #5
//   Equality Equations: NONE
//   Conservation Equation:
inertia1.flange_a.tau = 0;

빈 연결 집합(즉, 연결 집합 #5)의 경우 집합에 변수가 하나만 있으므로 등식이 생성되지 않습니다. 보존 방정식은 여전히 생성 되지만 하나의 항만 포함합니다.따라서 연결되지 않은 커넥터에서 아무 것도 흘러나올 수 없습니다. 이것은 직관으로 볼 수 있는 물리적 의미 또한 갖습니다.

이 모든 것이 물리적으로 무엇을 의미 할까요? 전기 연결의 경우 이는 각 연결이 커넥터 사이의 "완벽한 단락"으로 취급될 수 있음을 의미합니다.기계 시스템의 경우 연결은 관성이 없는 완전 강성 샤프트로 취급합니다.결론은 연결이란 각 커넥터의 전체 변수가 동일하고, 한 구성 요소를 떠나는 모든 보존된 양이 다른 구성 요소에 들어가야 함을 의미한다는 것입니다.구성 요소 사이에 아무 것도 손실되거나 저장되지 않습니다.

보존(Conservation)¶

이 방정식에는 두 가지 중요한 결과가 있습니다. 첫 번째는 flow 변수가 자동으로 보존된다는 것입니다. 일반적인 유량 변수는 전류, 토크, 질량 유량 등입니다.이들은 항상 보존된 양(각각 *즉, * 전하, 각 운동량 및 질량)의 시간 미분이므로 이러한 방정식은 자동으로 이러한 변수를 보존합니다.

그러나 다른 것도 암묵적으로 보존되고 있습니다. 구체적으로, 에너지 보존도 보장 할 수 있습니다. 이러한 모든 도메인에 대해 커넥터를 통한 전력 흐름은 통과 변수와 교차 변수 또는 교차 변수의 파생물의 곱으로 나타낼 수 있습니다. 결과적으로 각 도메인 연결 세트에 대해 자동으로 생성된 방정식에서 전력 보존 방정식을 쉽게 도출할 수 있습니다. 위의 예제에서 첫 번째 연결 세트에 다음 방정식이 있음을 알고 있습니다.

ground.flange_a.phi = damper2.flange_b.phi;
damper2.flange_b.phi = spring2.flange_b.phi;
ground.flange_a.tau + damper2.flange_b.tau + spring2.flange_b.tau = 0;

마지막 방정식에 ground.flange_a 커넥터의 각속도인 der(ground.flange_a.phi) 를 곱하면 다음과 같은 결과를 얻습니다.

der(ground.flange_a.phi)*ground.flange_a.tau
+ der(ground.flange_a.phi)*damper2.flange_b.tau
+ der(ground.flange_a.phi)*spring2.flange_b.tau = 0;

그러나 연결 집합의 모든 교차 변수가 동일하다는 것도 알고 있습니다. 결과적으로 이들의 미분도 동일해야 합니다. 이것은 그들 중 하나를 다른 것으로 대체할 수 있음을 의미합니다. 이러한 두 가지 대체를 수행하면 다음이 생성됩니다.

der(ground.flange_a.phi)*ground.flange_a.tau
+ der(damper2.flange_b.phi)*damper2.flange_b.tau
+ der(spring2.flange_b.phi)*spring2.flange_b.tau = 0;

위 방정식의 첫 번째 항은 flange_a 를 통해 접지 구성 요소로 흐르는 전력입니다. 두 번째 항은 flange_b 를 통해 damper2 구성 요소로 흐르는 힘입니다. 마지막 항은 flange_b 를 통해 spring2 구성 요소로 흐르는 힘입니다. 이들은 연결 세트의 모든 커넥터를 통해 흐르는 전력을 나타내므로 이는 해당 연결 세트에 의해 전력이 보존됨을 의미합니다(즉 한 구성 요소에서 흐르는 모든 전력은 다른 구성 요소로 흘러야 하며 손실되거나 저장되는 것은 없습니다).

균형잡힌 구성요소(Balanced Components)¶

연결 집합의 비인과적 변수를 포함하여 생성된 방정식에 대한 이전 논의를 주의 깊게 살펴보면매우 흥미로운 것을 볼 수 있습니다. 그러나 이를 보려면 먼저 커넥터 및 커넥터 세트에 대해 배운 몇 가지 사항을 검토해야 합니다.

1. 연결은 하나의 연결 세트에만 속할 수 있습니다.

2. 비인과적 변수(Acausal Variables) 에 대한 이전 논의에서 배웠듯이 커넥터의 모든 통과 변수(즉, flow 한정자로 선언된 변수)에 대해 변수(즉, 한정자가 없는 변수)와 일치하는 항목이 있어야 합니다.

3. 연결 세트에서 생성된 방정식의 수는 연결 세트의 커넥터 수에 커넥터의 통과(through)-(교차)across 쌍 수를 곱한 것과 같습니다.

비인과적 변수는 쌍으로 나온다는 것을 기억하십시오. 이러한 변수의 절반(쌍당 하나)에 대한 방정식은 연결을 통해 자동으로 생성됩니다. 즉, 방정식의 나머지 절반은 구성 요소 모델 자체에서 가져와야 합니다.

이 논의는 커넥터의 비인과적 변수에만 초점을 맞추고 있습니다.또한 다른 두 가지 경우도 고려해야 합니다.

1. 구성 요소 모델 내에서 선언된 변수(커넥터가 아닌).

2. 커넥터의 원인 변수(i.e. input 또는 output 에 의해 한정된 변수).

모델리카는 모든 비``partial`` 모델이 균형을 이루도록 요구합니다.그러나 그것은 무엇을 의미하는 걸까요? 이는 구성 요소가 적절한 수의 방정식을 제공해야 함을 의미합니다(필요 이상도 이하도 아님).문제는 필요한 방정식의 수를 계산하는 방법입니다.

비인과적 변수에 대한 논의를 기반으로 이미 시작했습니다. 비인과적 변수에 필요한 방정식의 절반은 생성된 방정식에서 가져오므로 나머지 절반은 이러한 커넥터를 포함하는 구성 요소 모델 내에서 가져와야 합니다. 특히 구성 요소는 각 커넥터의 모든 관통 쌍에 대해 하나의 방정식을 제공해야 합니다. 또한 output 한정자가 있는 커넥터의 모든 변수에 대해 하나의 방정식을 제공해야 합니다(참고: 구성 요소는 input 한정자가 있는 커넥터의 변수에 대해 방정식을 제공할 필요가 없습니다).여기서 이론적 근거는 구성 요소가 모든 input 신호가 알려져 있고(외부적으로 지정됨) 자신이 연결하는 모든 output 신호를 계산할 책임이 있다고 가정할 수 있다는 것입니다. 마지막으로 구성 요소 내에서 선언된 모든 (paramter 가 아닌) 변수에도 방정식이 있어야 합니다.

요약하면 구성 요소가 제공해야 하는 방정식의 수는 다음의 합계입니다.

1. 모든 커넥터에 걸친 관통 쌍의 수

2. 구성 요소 모델에서 선언된 비``파라미터`` 변수의 수.

3. 모든 커넥터에 걸쳐 있는 output 변수의 수.

이러한 방정식은 상속된 partial 모델에서 발생할 수 있습니다(그리고 자주 발생함).

구성 요소에서 제공하는 방정식의 수가 필요한 방정식의 수와 같으면 구성 요소 모델의 균형 이 맞다고 합니다.

경고(assert)¶

모델 제한을 적용하는 방법을 이해하려면 먼저 assert 기능을 알아야합니다.``assert`` 함수에 대한 호출 구문은 다음과 같습니다.

assert(conditional_expression, "Explanation of failure", assertLevel);

여기서 conditional_expression 은 true 또는 false 를 산출하는 표현식입니다. false 값은 어설션의 실패를 나타냅니다. 그 결과에 대해서는 나중에 잠시 논의할 것입니다. 두 번째 인수는 어설션이 실패한 이유를 설명하는 String 이어야 합니다. 마지막 인수인 assertLevel 은 AssertionLevel 자료형입니다(이전 enumerations 논의에서 정의됨). 이 마지막 인수는 선택 사항 이며 기본값은 AssertionalLevel.error 입니다.

이제 assert 함수를 사용하는 방법을 알았으니, 왜 그들이 중요한지 이해하기 위해 시뮬레이션 동안 어서션의 결과를 조사해 보겠습니다.

모델 제한 정의(Defining Model Limitations)¶

컴포넌트 모델 (또는 모델)을 생성할 때 방정식을 모델에 직접 포함하여 방정식에 대한 제한을 통합하는 것이 유용합니다. 이것은 equation 또는 algorithm 섹션에 assert 호출을 추가하여 수행됩니다. 이름에서 알 수 있듯이 이러한 주장은 특정 조건이 항상 참이어야 한다고 주장합니다.

모델 내의 방정식이 특정 조건에서만 정확하거나 적용 가능한 경우 이러한 조건이 어설션을 통해 모델에 포함되어야 합니다.그렇지 않으면 모델이 자동으로 잘못된 해을 산출할 수 있습니다.발견되지 않으면 모델 해을 기반으로 잘못된 결정을 내릴 수 있습니다. 이러한 모델이 후에 적발되면 모델에 대한 사람들의 신뢰가 약화될 것입니다. 따라서 항상 이러한 모델 제한 사항을 사전에 포착할 수 있도록 노력해야 합니다.

시뮬레이션 중에 이러한 주장이 어떤 영향을 미치는지 이해하는 데 잠시 시간을 할애할 가치가 있습니다. 시뮬레이션 프로세스의 일부는 소위 후보 해 을 생성하는 것입니다. 이러한 해은 실제 해가 될 수도 있고 그렇지 않을 수도 있습니다.그들은 일반적으로 기본 솔버가 해을 제안하고 해당하는"해"가 일부 수치 허용오차 내에서 정확한지 확인하기 위해 생성합니다.부정확한 것으로 확인된 후보 해은 일반적으로 충분히 정확한 해을 찾을 때까지 어떤 방식으로든 정제합니다.

후보 해가 어설션을 위반하면 자동으로 부정확한 것으로 간주합니다. 위반된 어설션은 바라건대 자동으로 더 정확하고 어설션을 위반하지 않는 해을 찾기 위해 노력합니다. 그러나 이러한 개선 프로세스가 충분히 정확한 해(즉, 허용 가능한 허용 오차 내에서 정확도 요구 사항을 충족)를 찾지 못하고, 여전히 시스템의 어설션을 위반하는 경우 시뮬레이션 환경은 두 가지 중 하나를 수행합니다. assert 호출의 level 인수가 AssertionLevel.error 이면 시뮬레이션이 종료되고, 반면에 level 인수가 AssertionLevel.warning 이면 어설션 설명이사용자에게 경고 메시지를 생성하는 데 사용합니다.이 메시지가 전달되는 방식은 각 시뮬레이션 환경에 따라 다릅니다. level 인수의 기본값(assert 호출에서 제공되지 않은 경우)은 AssertionLevel.error 임을 기억해야 합니다.